resource "kubernetes_secret_v1" "redis_secret" {
  metadata {
    name      = var.redis_secret_name
    namespace = var.namespace
  }

  data = {
    password = base64encode(var.redis_password)
  }

  type = "Opaque"
}

resource "kubernetes_config_map_v1" "redis_config" {
  metadata {
    name      = var.redis_configmap_name
    namespace = var.namespace
  }

  data = {
    "redis.conf" = <<EOF
requirepass REDIS_PASSWORD_PLACEHOLDER
maxmemory 256mb
maxmemory-policy allkeys-lru
save ""
appendonly no
tcp-keepalive 60
timeout 300
EOF
  }
}

resource "kubernetes_deployment_v1" "redis" {
  metadata {
    name      = var.redis_name
    namespace = var.namespace

    labels = {
      app = var.redis_name
    }
  }

  spec {
    replicas = 1

    selector {
      match_labels = {
        app = var.redis_name
      }
    }

    template {
      metadata {
        labels = {
          app = var.redis_name
        }
      }

      spec {
        init_container {
          name  = "config"
          image = var.redis_image

          command = ["sh", "-c"]

          args = [
            "cp /tmp/redis/redis.conf /etc/redis/redis.conf && sed -i \"s/REDIS_PASSWORD_PLACEHOLDER/$REDIS_PASSWORD/g\" /etc/redis/redis.conf"
          ]

          env {
            name = "REDIS_PASSWORD"

            value_from {
              secret_key_ref {
                name = kubernetes_secret_v1.redis_secret.metadata[0].name
                key  = "password"
              }
            }
          }

          volume_mount {
            name       = "redis-config"
            mount_path = "/tmp/redis"
          }

          volume_mount {
            name       = "config"
            mount_path = "/etc/redis"
          }
        }

        container {
          name  = "redis"
          image = var.redis_image

          command = [
            "redis-server",
            "/etc/redis/redis.conf"
          ]

          port {
            container_port = 6379
            name           = "redis"
          }

          env {
            name = "REDIS_PASSWORD"

            value_from {
              secret_key_ref {
                name = kubernetes_secret_v1.redis_secret.metadata[0].name
                key  = "password"
              }
            }
          }

          resources {
            requests = {
              cpu    = var.min_cpu
              memory = var.min_mem
            }

            limits = {
              cpu    = var.max_cpu
              memory = var.max_mem
            }
          }

          volume_mount {
            name       = "config"
            mount_path = "/etc/redis"
          }

          volume_mount {
            name       = "redis-storage"
            mount_path = "/data"
          }

          liveness_probe {
            exec {
              command = ["sh", "-c", "redis-cli -a $REDIS_PASSWORD ping"]
            }

            initial_delay_seconds = 30
            period_seconds        = 10
          }

          readiness_probe {
            exec {
              command = ["sh", "-c", "redis-cli -a $REDIS_PASSWORD ping"]
            }

            initial_delay_seconds = 5
            period_seconds        = 5
          }
        }

        volume {
          name = "redis-config"

          config_map {
            name = kubernetes_config_map_v1.redis_config.metadata[0].name
          }
        }

        volume {
          name = "config"
          empty_dir {}
        }

        volume {
          name = "redis-storage"

          persistent_volume_claim {
            claim_name = kubernetes_persistent_volume_claim_v1.redis_pvc.metadata[0].name
          }
        }
      }
    }
  }
}

resource "kubernetes_service_v1" "redis" {
  metadata {
    name      = var.redis_name
    namespace = var.namespace

    labels = {
      app = var.redis_name
    }
  }

  spec {
    selector = {
      app = var.redis_name
    }

    port {
      name        = "redis"
      port        = var.port
      target_port = var.port
      protocol    = "TCP"
    }

    type = "ClusterIP"
  }
}